 10  TEXT : NORMAL : HOME 
 110  INVERSE : PRINT  SPC( 40): PRINT " "
 210  FOR A = 2 TO 5: NORMAL : VTAB A: INVERSE : PRINT " ";: NORMAL : PRINT  TAB( 40): INVERSE : PRINT " ": NEXT A
 310  VTAB 6: INVERSE : PRINT  SPC( 40)
 410  VTAB 1: HTAB 1: PRINT "\";: HTAB 40: PRINT "/"
 510  VTAB 6: HTAB 1: PRINT "/";: HTAB 40: PRINT "\"
 610  NORMAL : VTAB 2: HTAB 4: PRINT "ProDOS Cheat & Cracker Maker v1.0"
 710  VTAB 3: HTAB 13: PRINT "Written by -DC-"
 810  VTAB 4: HTAB 11: PRINT "Call Shooting Star:"
 910  VTAB 5: HTAB 3: PRINT "20 meg BBS/PAE ProDOS...206/838-7686"
 1010  VTAB 7: POKE 34,6: PRINT 
 1110 D$ =  CHR$ (13) +  CHR$ (4): DIM CT(64),T(64),B(64),S(64),F(64)
 1115  POKE 49168,0
 1120  INPUT "Load in a hi-res picture? ";Y$: IF Y$ = "y" THEN Y$ = "Y"
 1135  IF Y$ <  > "Y" THEN 1210
 1140  PRINT : PRINT "Insert your disk now.": INPUT "Filename: ";Y$: POKE 44033,17: IF Y$ = "" THEN 1140
 1145  PRINT D$"BLOAD"Y$: POKE 44033,16:PI = 1
 1150  VTAB 15: HTAB 8: FLASH : PRINT "RE-INSERT C&C MAKER DISK": NORMAL 
 1155  FOR A = 1 TO 5000: NEXT 
 1210  HOME : PRINT : PRINT "Enter four 39 character lines for"
 1310  PRINT "the top four lines -": PRINT 
 1410  FOR A = 1 TO 39: PRINT "-";: NEXT : PRINT :B =  PEEK (37) + 5: VTAB B: FOR A = 1 TO 39: PRINT "-";: NEXT : PRINT :B =  PEEK (37) - 4: VTAB B
 1510  FOR A = 1 TO 4: INPUT "";D$(A)
 1610  IF  LEFT$ (D$(A),2) <  > "R>" THEN 1810
 1710 X$(A) = "": FOR X = 1 TO 39:X$(A) = X$(A) +  MID$ (D$(A),3,1): NEXT :D$(A) = X$(A)
 1810  IF  LEFT$ (D$(A),2) <  > "C>" THEN 1840
 1820 X$(A) =  MID$ (D$(A),3,39):B =  LEN (X$(A)): IF B > 37 THEN  VTAB 23: HTAB 8: PRINT  CHR$ (7);"  Too long, try again.":A = A - 1: VTAB 12 + A: NEXT 
 1830 X = (39 - B) / 2:D$(A) = "": FOR B = 1 TO X:D$(A) = D$(A) + " ": NEXT B:D$(A) = D$(A) + X$(A) + "                                     ":D$(A) =  LEFT$ (D$(A),39)
 1840  IF  LEFT$ (D$(A),2) <  > "B>" THEN 1860
 1850 D$(A) = "": FOR B = 1 TO 39:D$(A) = D$(A) + " ": NEXT 
 1860  IF  LEN (D$(A)) < 39 THEN DD = 39 -  LEN (D$(A)): FOR DC = 1 TO DD:D$(A) = D$(A) + " ": NEXT DC
 1900  NEXT 
 1910  HOME : FOR A = 1 TO 4: PRINT D$(A): NEXT : PRINT : INPUT "Does this look okay? ";Y$: IF Y$ = "y" THEN Y$ = "Y"
 1915  IF Y$ <  > "Y" THEN 1210
 2010  PRINT : INPUT "Inverse any lines? ";Y$: IF Y$ = "y" THEN Y$ = "Y"
 2015  IF Y$ <  > "Y" THEN 2410
 2110  PRINT : INPUT "Inverse line #";X: IF X < 1 OR X > 4 THEN 1810
 2120 IN(X) = 1
 2310  INPUT "Inverse another? ";Y$: IF Y$ = "Y" OR Y$ = "y" THEN 2110
 2410  HOME : PRINT 
 2420  INPUT "Allow user to restore data? ";FR$: PRINT 
 2510  PRINT "Now select what to modify (decimal) -": PRINT :X = 1
 2610  INPUT "Track  :";T(X)
 2710  INPUT "Sector :";S(X): INPUT "Byte   :";B(X)
 2720  IF FR$ = "Y" OR FR$ = "y" THEN  INPUT "From   :";F(X)
 2730  INPUT "To     :";CT(X)
 2810  PRINT : INPUT "Change another location? ";Y$: IF Y$ = "y" THEN Y$ = "Y"
 2815  IF Y$ <  > "Y" THEN 3010
 2910 X = X + 1: IF X = 63 THEN  PRINT : PRINT "That's the maximum!": GOTO 3015
 2920  PRINT : GOTO 2610
 3010  HOME 
 3015  PRINT : PRINT "Building binary file...";
 3110  PRINT D$"BLOAD FILE":LA = 16767 - 1
 3210  FOR A = 1 TO 4: FOR B = 1 TO 39:Y =  ASC ( MID$ (D$(A),B,1)) + 128: IF IN(A) = 1 THEN Y = Y - 128
 3220  POKE LA + B,Y: NEXT B:LA = LA + 40: POKE LA,141: NEXT A
 3310  POKE 17610,X * 5: POKE 17608,0: POKE 17609,0: REM  %> Total bytes, I/R data reset, and picture to 0
 3410  FOR A = 0 TO (X - 1): POKE 17611 + (A * 5),CT(A + 1): POKE 17612 + (A * 5),F(A + 1): POKE 17613 + (A * 5),B(A + 1): POKE 17614 + (A * 5),S(A + 1): POKE 17615 + (A * 5),T(A + 1): NEXT A
 3420  IF PI = 1 THEN  POKE 8189,76: POKE 8190,0: POKE 8191,64: POKE 17609,1
 3430  POKE 17607,0: IF FR$ = "Y" OR FR$ = "y" THEN  POKE 17607,1
 3510  PRINT : PRINT : HTAB 3: PRINT "INSERT A BLANK DISK AND HIT A KEY";
 3515  IF  PEEK (49152) < 128 THEN  GOTO 3515
 3610  POKE 49168,0: HOME : PRINT : PRINT "Saving the file...";
 3700  POKE 44033,17: REM   %> Changes track location!
 3705  IF PI = 0 THEN  PRINT D$"BSAVE FILE,A$4000,L"1227 + (X * 5): GOTO 3810
 3710  PRINT D$"BSAVE FILE,A$1FFD,L"9422 + (X * 5)
 3810  HOME : PRINT : PRINT : PRINT "Your cheat has been made under the": PRINT "filename of 'FILE'.  Rename it": PRINT "to whatever you wish."
 3910  PRINT : PRINT : HTAB 2
 4010  PRINT "INSERT A DISK TO BOOT AND HIT A KEY";
 4020  IF  PEEK (49152) < 128 THEN 4020
 4030  POKE 49168,0: PR# 6
